blob: 5f207b0375b1a8d7e81d81b33b7c6f9d6d586983 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id: PKGBUILD 106042 2014-02-21 16:17:57Z andyrtr $
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Sébastien Luttringer
pkgbase=virtualbox-modules-lts
pkgname=('virtualbox-host-modules-lts' 'virtualbox-guest-modules-lts')
pkgver=4.3.6
pkgrel=6
arch=('i686' 'x86_64')
url='http://virtualbox.org'
license=('GPL')
makedepends=('linux-lts>=3.10' 'linux-lts<3.11'
'linux-lts-headers>=3.10' 'linux-lts-headers<3.11'
"virtualbox-host-dkms>=$pkgver"
"virtualbox-guest-dkms>=$pkgver")
# remember to also adjust the .install files and the package deps below
_extramodules=extramodules-3.10-lts
build() {
_kernver=$(cat /usr/lib/modules/$_extramodules/version)
# dkms need modification to be run as user
cp -r /var/lib/dkms .
echo "dkms_tree='$srcdir/dkms'" > dkms.conf
# build host modules
msg2 'Host modules'
dkms --dkmsframework dkms.conf build "vboxhost/$pkgver" -k "$_kernver"
# build guest modules
msg2 'Guest modules'
dkms --dkmsframework dkms.conf build "vboxguest/$pkgver" -k "$_kernver"
}
package_virtualbox-host-modules-lts(){
_kernver=$(cat /usr/lib/modules/$_extramodules/version)
pkgdesc='Host kernel modules for VirtualBox'
depends=('linux-lts>=3.10' 'linux-lts<3.11')
replaces=('virtualbox-modules-lts')
conflicts=('virtualbox-modules-lts')
provides=("virtualbox-host-modules=$pkgver")
install=virtualbox-host-modules-lts.install
cd "dkms/vboxhost/$pkgver/$_kernver/$CARCH/module"
install -dm755 "$pkgdir/usr/lib/modules/$_extramodules/"
install -m644 * "$pkgdir/usr/lib/modules/$_extramodules/"
find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
}
package_virtualbox-guest-modules-lts(){
_kernver=$(cat /usr/lib/modules/$_extramodules/version)
pkgdesc='Guest kernel modules for VirtualBox'
license=('GPL')
depends=('linux-lts>=3.10' 'linux-lts<3.11')
replaces=('virtualbox-archlinux-modules-lts')
conflicts=('virtualbox-archlinux-modules-lts')
provides=("virtualbox-guest-modules=$pkgver")
install=virtualbox-guest-modules-lts.install
cd "dkms/vboxguest/$pkgver/$_kernver/$CARCH/module"
install -dm755 "$pkgdir/usr/lib/modules/$_extramodules/"
install -m644 * "$pkgdir/usr/lib/modules/$_extramodules/"
find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
}
# vim:set ts=2 sw=2 et:
md5sums=()
|
