blob: f28badfda6e58cad7773be1441235eb6ece3811e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
|
# $Id: PKGBUILD 63763 2012-02-05 12:13:00Z ibiru $
#Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=virtualbox
pkgname=('virtualbox' 'virtualbox-archlinux-additions' 'virtualbox-sdk' 'virtualbox-source')
pkgver=4.1.8
pkgrel=2
arch=('i686' 'x86_64')
url='http://virtualbox.org'
license=('GPL' 'custom')
makedepends=('libstdc++5' 'bin86' 'dev86' 'iasl' 'libxslt' 'libxml2' 'libxcursor' 'qt' 'libidl2' 'sdl_ttf' 'alsa-lib' 'libpulse' 'libxtst'
'xalan-c' 'sdl' 'libxmu' 'curl' 'python2' 'linux-headers' 'mesa' 'libxrandr' 'libxinerama' 'libvncserver' 'openjdk6' 'gsoap' 'vde2')
#'xorg-server-devel' 'xf86driproto' 'libxcomposite')
[[ $CARCH == "x86_64" ]] && makedepends=("${makedepends[@]}" 'gcc-multilib' 'lib32-glibc')
source=(http://download.virtualbox.org/virtualbox/${pkgver}/VirtualBox-${pkgver}.tar.bz2
UserManual-$pkgver.pdf::http://download.virtualbox.org/virtualbox/${pkgver}/UserManual.pdf
10-vboxdrv.rules vboxdrv-reference.patch LocalConfig.kmk vboxbuild
change_default_driver_dir.patch vbox-service.conf vbox-service.rc)
_extramodules=extramodules-3.2-ARCH
_kernver="$(cat /lib/modules/${_extramodules}/version)"
build() {
cd "$srcdir/VirtualBox-${pkgver}_OSE"
patch -Np1 -i "$srcdir/vboxdrv-reference.patch"
patch -Np1 -i "$srcdir/change_default_driver_dir.patch"
cp "$srcdir/LocalConfig.kmk" .
./configure --disable-docs \
--enable-webservice \
--enable-vde \
--enable-vnc \
--nofatal \
--with-linux=/usr/src/linux-${_kernver}
source ./env.sh
kmk all
sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' "out/linux.$BUILD_PLATFORM_ARCH/release/bin/vboxshell.py"
}
package_virtualbox() {
pkgdesc="Powerful x86 virtualization for enterprise as well as home use"
depends=('virtualbox-modules' 'libxml2' 'libxcursor' 'libxinerama' 'sdl' 'libxmu' 'curl' 'libvncserver' 'libpng')
optdepends=('qt: for VirtualBox GUI'
'vde2: Virtual Distributed Ethernet support'
'virtualbox-sdk: developer kit'
'virtualbox-source: host kernel source modules for non-stock kernels')
backup=('etc/vbox/vbox.cfg')
replaces=('virtualbox-ose')
conflicts=('virtualbox-ose')
install=virtualbox.install
source "$srcdir/VirtualBox-${pkgver}_OSE/env.sh"
cd "$srcdir/VirtualBox-${pkgver}_OSE/out/linux.$BUILD_PLATFORM_ARCH/release/bin"
mkdir -p "$pkgdir"/usr/{bin,lib/virtualbox/components,lib/virtualbox/ExtensionPacks,share/virtualbox/nls}
#doc
install -m 0644 "$srcdir/UserManual-$pkgver.pdf" "$pkgdir/usr/share/virtualbox/UserManual.pdf"
#Binaries and Wrapper with Launchers
install -m 0755 VBox.sh "$pkgdir/usr/bin/VBox"
for i in VBoxHeadless vboxheadless VBoxManage vboxmanage VBoxSDL vboxsdl VirtualBox virtualbox vboxwebsrv VBoxBalloonCtrl vboxballoonctrl; do
ln -sf VBox "$pkgdir/usr/bin/$i"
done
install -m 0755 VBoxTunctl "$pkgdir/usr/bin"
#components
install -m 0755 components/* -t "$pkgdir/usr/lib/virtualbox/components"
#lib
install -m 0755 *.so "$pkgdir/usr/lib/virtualbox"
install -m 0644 *.gc *.r0 VBoxEFI*.fd "$pkgdir/usr/lib/virtualbox"
#setuid root binaries
install -m 4755 VBoxSDL VirtualBox VBoxHeadless VBoxNetDHCP VBoxNetAdpCtl -t "$pkgdir/usr/lib/virtualbox"
#other binaries
install -m 0755 VBoxManage VBoxSVC VBoxExtPackHelperApp VBoxXPCOMIPCD VBoxTestOGL VBoxBalloonCtrl vboxwebsrv webtest -t "$pkgdir/usr/lib/virtualbox"
#language
install -m 0755 nls/*.qm -t "$pkgdir/usr/share/virtualbox/nls"
#useless scripts
install -m 0755 VBoxCreateUSBNode.sh VBoxSysInfo.sh -t "$pkgdir/usr/share/virtualbox"
#icons
install -D -m 0644 VBox.png "$pkgdir/usr/share/pixmaps/VBox.png"
pushd icons
for i in *; do
install -d "$pkgdir/usr/share/icons/hicolor/$i/mimetypes"
cp $i/* "$pkgdir/usr/share/icons/hicolor/$i/mimetypes"
done
popd
#desktop
install -D -m 0644 virtualbox.desktop "$pkgdir/usr/share/applications/virtualbox.desktop"
install -D -m 0644 virtualbox.xml "$pkgdir/usr/share/mime/packages/virtualbox.xml"
#install configuration
mkdir -p "$pkgdir/etc/vbox"
echo 'INSTALL_DIR=/usr/lib/virtualbox' > "$pkgdir/etc/vbox/vbox.cfg"
#udev and licence
install -D -m 0644 "$srcdir/VirtualBox-${pkgver}_OSE/COPYING" \
"$pkgdir/usr/share/licenses/virtualbox/LICENSE"
install -D -m 0644 "$srcdir/10-vboxdrv.rules" \
"$pkgdir/lib/udev/rules.d/10-vboxdrv.rules"
}
package_virtualbox-source() {
pkgdesc="VirtualBox kernel modules source"
depends=(gcc make)
provides=(virtualbox-modules)
optdepends=('linux-headers'
'kernel26-lts-headers')
install=virtualbox-source.install
source "$srcdir/VirtualBox-${pkgver}_OSE/env.sh"
mkdir -p $pkgdir/usr/lib/virtualbox
cd "$srcdir/VirtualBox-${pkgver}_OSE/out/linux.$BUILD_PLATFORM_ARCH/release/bin"
#sources for modules
cp -r src ${pkgdir}/usr/lib/virtualbox
#install compilation script
install -D -m 755 "${srcdir}/vboxbuild" "${pkgdir}/usr/bin/vboxbuild"
}
package_virtualbox-sdk() {
pkgdesc="VirtualBox Software Developer Kit (SDK)"
depends=('python2')
mkdir -p "$pkgdir/usr/lib/virtualbox"
source "$srcdir/VirtualBox-${pkgver}_OSE/env.sh"
cd "$srcdir/VirtualBox-${pkgver}_OSE/out/linux.$BUILD_PLATFORM_ARCH/release/bin"
install -D -m 0755 vboxshell.py "$pkgdir/usr/lib/virtualbox/vboxshell.py"
#python sdk
pushd sdk/installer
VBOX_INSTALL_PATH="/usr/lib/virtualbox" python2 vboxapisetup.py install --root "${pkgdir}"
popd
rm -rf sdk/installer
mv sdk "$pkgdir/usr/lib/virtualbox"
}
package_virtualbox-archlinux-additions(){
pkgdesc="Additions only for Arch Linux guests (userspace tools)"
depends=("virtualbox-archlinux-modules=$pkgver" 'gcc-libs' 'libxmu' 'xorg-xrandr' 'libxfixes')
replaces=('virtualbox-guest-additions')
conflicts=('virtualbox-guest-additions')
source "$srcdir/VirtualBox-${pkgver}_OSE/env.sh"
cd "$srcdir/VirtualBox-${pkgver}_OSE/out/linux.$BUILD_PLATFORM_ARCH/release/bin/additions"
install -d "$pkgdir"/{usr/bin,sbin}
install -m755 VBoxClient VBoxControl VBoxService "$pkgdir/usr/bin"
install -m755 mount.vboxsf "$pkgdir/sbin"
install -m755 -D "$srcdir"/VirtualBox-${pkgver}_OSE/src/VBox/Additions/x11/Installer/98vboxadd-xclient \
"$pkgdir"/usr/bin/VBoxClient-all
install -m755 -D "$srcdir"/VirtualBox-${pkgver}_OSE/src/VBox/Additions/x11/Installer/vboxclient.desktop \
"$pkgdir"/etc/xdg/autostart/vboxclient.desktop
install -D vboxvideo_drv_111.so \
"$pkgdir/usr/lib/xorg/modules/drivers/vboxvideo.so"
install -d "$pkgdir/usr/lib/xorg/modules/dri"
install -m755 VBoxOGL*.so "$pkgdir/usr/lib"
ln -s /usr/lib/VBoxOGL.so "$pkgdir/usr/lib/xorg/modules/dri/vboxvideo_dri.so"
install -m755 -D pam_vbox.so "$pkgdir/lib/security/pam_vbox.so"
# install rc.d script
install -D -m755 "${srcdir}/vbox-service.rc" "${pkgdir}/etc/rc.d/vbox-service"
# install sample config
install -D -m644 "${srcdir}/vbox-service.conf" "${pkgdir}/etc/conf.d/vbox-service"
}
md5sums=('2092bba46baa62fab5520d67dee2ece8'
'2f6b36ff143eb8da55ee92676708e757'
'5f85710e0b8606de967716ded7b2d351'
'6ab2455c391d8cc005e2f4461ae26a3b'
'78ffa67ff131680f1d2b6f06d4325c5b'
'67688bff176d3c6fac5664dc282fea52'
'97e193f050574dd272a38e5ee5ebe62b'
'3c08ad30b89add47d3f45121200a5360'
'e7416331d0bc331f3b5aae3e5d104642')
|
