blob: de7c26dba80861875acaabe1d8fcdf9fcc81b369 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Maintainer: Thomas Dziedzic < gostrc at gmail >
# Contributor: leepesjee <lpeschier at xs4all dot nl>
# Contributor: Olivier Medoc
# Contributor: ignotus
# Contributor: Fabian Moser
# Contributor: djscholl
pkgname=vtk
pkgver=5.6.1
pkgrel=6
pkgdesc='A software system for 3D computer graphics, image processing, and visualization which supports a wide variety of visualization algorithms and advanced modeling techniques.'
arch=('i686' 'x86_64' 'mips64el')
url='http://www.vtk.org'
license=('BSD')
depends=('libpng' 'libtiff' 'freetype2' 'python2' 'java-runtime' 'tk' 'boost' 'ffmpeg' 'qt' 'lesstif' 'mysql')
optdepends=('gnuplot: plotting tools'
'graphviz: drawing tools')
makedepends=('cmake' 'java-environment' 'doxygen' 'gnuplot' 'mesa')
source=("http://www.vtk.org/files/release/${pkgver:0:3}/${pkgname}-${pkgver}.tar.gz"
"http://www.vtk.org/files/release/${pkgver:0:3}/vtkdata-${pkgver}.tar.gz"
'missingheader.diff')
md5sums=('b80a76435207c5d0f74dfcab15b75181'
'67263bd972f923d39a60f01104368779'
'f7c60ac3ccaf61c41ca508e53d895d3e')
build() {
cd VTK
# remove next time version bump
patch -Np1 -i ${srcdir}/missingheader.diff
# remove next time version bump
sed -i '31 i#include <vtksys/cstddef>' Common/vtkPythonUtil.cxx
# fix for libpng 1.4
for _FILE in `grep -Rl "png_set_gray_1_2_4_to_8" *`
do
sed -i 's|png_set_gray_1_2_4_to_8|png_set_expand_gray_1_2_4_to_8|' ${_FILE}
done
cd ${srcdir}
rm -rf build
mkdir build
cd build
cmake \
-Wno-dev \
-DBUILD_SHARED_LIBS:BOOL=ON \
-DCMAKE_INSTALL_PREFIX:FILEPATH=/usr \
-DVTK_DATA_ROOT:FILEPATH=${srcdir}/VTKData \
-DBUILD_DOCUMENTATION:BOOL=ON \
-DDOCUMENTATION_HTML_HELP:BOOL=ON \
-DDOCUMENTATION_HTML_TARZ:BOOL=ON \
-DBUILD_EXAMPLES:BOOL=ON \
-DVTK_USE_HYBRID:BOOL=ON \
-DVTK_USE_PARALLEL:BOOL=ON \
-DVTK_USE_PATENTED:BOOL=ON \
-DVTK_USE_SYSTEM_EXPAT:BOOL=ON \
-DVTK_USE_SYSTEM_FREETYPE:BOOL=ON \
-DVTK_USE_SYSTEM_JPEG:BOOL=ON \
-DVTK_USE_SYSTEM_PNG:BOOL=ON \
-DVTK_USE_SYSTEM_TIFF:BOOL=ON \
-DVTK_USE_SYSTEM_ZLIB:BOOL=ON \
-DVTK_USE_SYSTEM_LIBXML2:BOOL=ON \
-DVTK_USE_BOOST:BOOL=ON \
-DVTK_USE_INFOVIS:BOOL=ON \
-DVTK_USE_GL2PS:BOOL=ON \
-DVTK_USE_MYSQL:BOOL=ON \
-DVTK_USE_FFMPEG_ENCODER:BOOL=ON \
-DVTK_USE_TEXT_ANALYSIS:BOOL=ON \
-DVTK_WRAP_JAVA:BOOL=ON \
-DVTK_WRAP_PYTHON:BOOL=ON \
-DVTK_WRAP_TCL:BOOL=ON \
-DVTK_PYTHON_SETUP_ARGS:STRING="--prefix=${pkgdir}/usr" \
-DVTK_USE_QT:BOOL=ON \
-DDESIRED_QT_VERSION:STRING=4 \
-DVTK_USE_GUISUPPORT:BOOL=ON \
-DCMAKE_CXX_FLAGS="-D__STDC_CONSTANT_MACROS" \
-DPYTHON_INCLUDE_DIR=/usr/include/python2.7 \
-DPYTHON_LIBRARY=/usr/lib/libpython2.7.so \
${srcdir}/VTK
# j1 is used because of a bug in building with multiple threads
make -j1
}
package() {
cd build
make DESTDIR=${pkgdir} install
# Move the vtk.jar to the arch-specific location
install -dv ${pkgdir}/usr/share/java/${pkgname}
mv -v ${pkgdir}/usr/lib/${pkgname}-${pkgver:0:3}/java/${pkgname}.jar \
${pkgdir}/usr/share/java/${pkgname}
# Move the qt-designer plugin to the appropriate location
install -dv ${pkgdir}/usr/lib/qt
mv -v ${pkgdir}/usr/plugins \
${pkgdir}/usr/lib/qt
# Install license
install -dv ${pkgdir}/usr/share/licenses/${pkgname}
install -m644 ${srcdir}/VTK/Copyright.txt \
${pkgdir}/usr/share/licenses/${pkgname}
# Put an entry in /etc/ld.so.conf.d
install -dv ${pkgdir}/etc/ld.so.conf.d
echo "/usr/lib/${pkgname}-${pkgver:0:3}" > ${pkgdir}/etc/ld.so.conf.d/${pkgname}.conf
}
|
