blob: d1bb79e117c46061e6dc302a3611b9e2b50e1d12 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 79057 2012-10-29 19:02:22Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Daenyth <Daenyth+Arch [at] gmail [dot] com>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Vitaliy Berdinskikh <skipper13@root.ua>
pkgname=xmlrpc-c
pkgver=1.32.2
pkgrel=1
epoch=1
pkgdesc='XML-RPC for C and C++'
arch=('x86_64' 'i686')
url='http://xmlrpc-c.sourceforge.net/'
license=('custom')
depends=('curl' 'libxml2')
makedepends=('libtool' 'setconf')
options=('!makeflags' '!libtool' '!emptydirs')
source=("$pkgname-advanced-$pkgver.tar.gz::http://xmlrpc-c.svn.sourceforge.net/viewvc/xmlrpc-c/advanced/?view=tar")
sha256sums=('2707de25dba9823eaa328072392f2c25f08ed6c707be300bfae8f945609f9c19')
build() {
cd "$srcdir/advanced"
[ "$CARCH" != "i686" ] && export CFLAGS="$CFLAGS -fPIC"
./configure --prefix=/usr \
--mandir=/usr/share/man \
--enable-libxml2-backend \
--disable-cgi-server \
--disable-libwww-client \
--disable-wininet-client \
--enable-abyss \
--enable-cplusplus
mkdir include/curl
touch include/curl/types.h
make CFLAGS_PERSONAL="$CFLAGS"
make CFLAGS_PERSONAL="$CFLAGS" -C tools
}
package() {
cd "$srcdir/advanced"
make DESTDIR="$pkgdir" install
make DESTDIR="$pkgdir" -C tools install
install -Dm644 doc/COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Remove references to build directory
setconf "$pkgdir/usr/bin/xmlrpc-c-config" BLDDIR ""
setconf "$pkgdir/usr/bin/xmlrpc-c-config" ABS_SRCDIR ""
}
# vim:set ts=2 sw=2 et:
|
