blob: 6e2977c70f14a969c6dc9b30daace14230b29d19 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 67084 2012-03-03 16:12:24Z tdziedzic $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: orbisvicis <gmail.com>
pkgname=xmonad-contrib
pkgver=0.10
pkgrel=2
pkgdesc="Add-ons for xmonad"
arch=('i686' 'x86_64' 'mips64el')
url="http://xmonad.org/"
license=('BSD')
depends=('ghc=7.4.1-2' 'xmonad=0.10-3' 'sh' 'haskell-x11=1.5.0.1-2' 'haskell-x11-xft=0.3.1-3' 'haskell-utf8-string=0.3.7-1' 'haskell-random=1.0.1.1-1')
install='xmonad-contrib.install'
source=(http://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
md5sums=('9a4353a94ec0ea3a9c4700757ef5ae81')
build() {
cd $srcdir/$pkgname-$pkgver
runhaskell Setup.lhs configure --ghc --enable-shared --enable-split-objs --prefix=/usr -fuse_xft \
--libsubdir=\$compiler/site-local/\$pkgid
runhaskell Setup build
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
cd $srcdir/$pkgname-$pkgver
install -D -m744 register.sh $pkgdir/usr/share/haskell/$pkgname/register.sh
install -m744 unregister.sh $pkgdir/usr/share/haskell/$pkgname/unregister.sh
runhaskell Setup.lhs copy --destdir=$pkgdir
install -D LICENSE $pkgdir/usr/share/licenses/xmonad-contrib/LICENSE
}
|
