blob: 0b32e20c45a2edb442ccc88eda308cd1ff39dfda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 88640 2013-04-20 21:08:12Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Patrick Smits <mail@patricksmits.net>
pkgname=yaws
pkgver=1.96
pkgrel=1
pkgdesc='Yet Another Web Server, pure Erlang HTTP server/framework'
arch=('x86_64' 'i686' 'mips64el')
url='http://yaws.hyber.org/'
license=('BSD')
depends=('pam' 'erlang')
backup=('etc/yaws/yaws.conf')
options=('!emptydirs')
install=$pkgname.install
optdepends=('erlang-nox: Erlang without X (headless)')
source=("http://yaws.hyber.org/download/$pkgname-$pkgver.tar.gz"
"$pkgname.service")
sha256sums=('8d4f16d18937335ac021ca4c65c8ee81dc4d71f133718c7148856cc6bf1f55e2'
'3f8347add6e3741e77f7bb9ba6b31feb1c878e2e58ecf19063891e801fa24698')
prepare() {
cd "$pkgname-$pkgver"
# python2 fix
for file in cgi.yaws cgi-bin/foo.py; do
sed -i '0,/on/s//on2/' "www/$file"
done
}
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -d "$pkgdir/usr/lib/erlang/lib"
ln -s /usr/lib/yaws "$pkgdir/usr/lib/erlang/lib/$pkgname-$pkgver"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 "$srcdir/$pkgname.service" \
"$pkgdir/usr/lib/systemd/system/$pkgname.service"
}
# vim:set ts=2 sw=2 et:
|
