community/znc/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# $Id: PKGBUILD 47765 2011-05-25 13:51:21Z tdziedzic $
# Maintainer: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: mickael9 <mickael9 at gmail dot com>

pkgname=znc
pkgver=0.098
pkgrel=3
pkgdesc='An IRC bouncer with modules & scripts support'
url='http://en.znc.in/wiki/index.php/ZNC'
license=('GPL2')
arch=('i686' 'x86_64' 'mips64el')

depends=('c-ares' 'gcc-libs' 'openssl')
makedepends=('swig' 'tcl' 'python' 'perl' 'cyrus-sasl')
optdepends=('tcl: modtcl module'
            'python: modpython module'
            'perl: modperl module'
            'cyrus-sasl: saslauth module')

source=("http://znc.in/releases/znc-${pkgver}.tar.gz")
md5sums=('5667b4acb1f01309d6eded77abac700c')

build() {
  cd znc-${pkgver}

  ./configure --prefix=/usr \
    --enable-sasl \
    --enable-tcl \
    --enable-python \
    --enable-perl \
    --enable-extra

  make
}

package() {
  cd znc-${pkgver}

  make DESTDIR=${pkgdir} install
}