blob: 30f3ad81afc0ca0a42c79cb2f27d231fce4482bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 123916 2011-05-14 10:31:07Z thomas $
# Maintainer: Thomas Bächler <thomas@archlinux.org>
pkgname=attr
pkgver=2.4.46
pkgrel=1
pkgdesc="Extended attribute support library for ACL support"
arch=('i686' 'x86_64')
url="http://savannah.nongnu.org/projects/attr"
license=('LGPL')
depends=('glibc')
makedepends=('gettext')
replaces=('xfsattr')
provides=('xfsattr')
conflicts=('xfsattr')
options=('!libtool')
source=(http://download.savannah.gnu.org/releases/${pkgname}/${pkgname}-${pkgver}.src.tar.gz)
sha256sums=('dcd69bdca7ff166bc45141eddbcf21967999a6b66b0544be12a1cc2fd6340e1f')
build() {
cd "${srcdir}"/${pkgname}-${pkgver}
export INSTALL_USER=root INSTALL_GROUP=root
./configure --prefix=/usr --libdir=/lib --libexecdir=/usr/lib
make
}
package() {
cd "${srcdir}"/${pkgname}-${pkgver}
make DIST_ROOT="${pkgdir}" install install-lib install-dev
# tidy up
rm -f "${pkgdir}"/lib/libattr.a
chmod 0755 "${pkgdir}"/lib/libattr.so.*.*.*
# remove conflicting manpages
rm -rf "${pkgdir}"/usr/share/man/man2
}
|
