blob: 018624ada8b85a571a47d0161b60a8d8dd39443b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 201684 2013-12-18 05:22:31Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>
pkgname=coreutils
pkgver=8.22
pkgrel=2
pkgdesc="The basic file, shell and text manipulation utilities of the GNU operating system"
arch=('i686' 'x86_64')
license=('GPL3')
url="http://www.gnu.org/software/coreutils"
groups=('base')
depends=('glibc' 'pam' 'acl' 'gmp' 'libcap' 'openssl')
install=${pkgname}.install
source=(ftp://ftp.gnu.org/gnu/$pkgname/$pkgname-$pkgver.tar.xz{,.sig})
md5sums=('8fb0ae2267aa6e728958adc38f8163a2'
'SKIP')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
./configure --prefix=/usr --libexecdir=/usr/lib --with-openssl \
--enable-no-install-program=groups,hostname,kill,uptime
make
}
check() {
cd ${srcdir}/${pkgname}-${pkgver}
make RUN_EXPENSIVE_TESTS=yes check
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
}
|
