blob: 128087d4ef0d3253ee5d184343a9282b6a5769ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Contributor: Kaiting Chen <kaiting.chen@kiwilight.com>
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
pkgname='cronie'
pkgver=1.4.9
pkgrel=5
pkgdesc='Daemon that runs specified programs at scheduled times and related tools'
url='https://fedorahosted.org/cronie/'
license=('custom:BSD')
arch=('i686' 'x86_64')
depends=('pam' 'bash' 'run-parts')
optdepends=('pm-utils: defer anacron on battery power'
'smtp-server: send job output via email'
'smtp-forwarder: forward job output to email server')
source=("https://fedorahosted.org/releases/c/r/${pkgname}/${pkgname}-${pkgver}.tar.gz"
'service'
'pam.d'
'deny')
sha1sums=('40405cb30b62bd60323e4daf5198f26f0e65c4c4'
'eb8ed1e22dbe9c02075fe4bbe925b6eeb9954649'
'5eff7fb31f6bc0a924243ff046704726cf20c221'
'0f279b8fb820340267d578dc85511c980715f91e')
backup=('etc/cron.deny'
'etc/pam.d/crond'
'etc/cron.d/0hourly'
'etc/anacrontab')
conflicts=('cron')
provides=('cron')
groups=('base')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--sbindir=/usr/bin \
--enable-anacron \
--with-inotify \
--with-pam \
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
chmod u+s "${pkgdir}"/usr/bin/crontab
install -d "${pkgdir}"/var/spool/{ana,}cron
install -d "${pkgdir}"/etc/cron.{d,hourly,daily,weekly,monthly}
install -Dm644 ../deny "${pkgdir}"/etc/cron.deny
install -Dm644 ../pam.d "${pkgdir}"/etc/pam.d/crond
install -Dm644 ../service "${pkgdir}"/usr/lib/systemd/system/cronie.service
install -Dm644 contrib/anacrontab "${pkgdir}"/etc/anacrontab
install -Dm644 contrib/0hourly "${pkgdir}"/etc/cron.d/0hourly
install -Dm755 contrib/0anacron "${pkgdir}"/etc/cron.hourly/0anacron
install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/cronie/COPYING
}
|
