blob: 42f0c785303c8569ec4f8ff5438a80f0d0856b12 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# $Id: PKGBUILD 196009 2013-10-07 11:50:04Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=glib2
pkgname=(glib2 glib2-docs)
pkgver=2.38.0
pkgrel=1
pkgdesc="Common C routines used by GTK+ and other libs"
url="http://www.gtk.org/"
arch=(i686 x86_64)
makedepends=('pkg-config' 'python2' 'libxslt' 'docbook-xml' 'pcre' 'libffi' 'elfutils')
source=(http://ftp.gnome.org/pub/GNOME/sources/glib/${pkgver%.*}/glib-$pkgver.tar.xz
revert-warn-glib-compile-schemas.patch)
sha256sums=('7513a7de5e814ccb48206340a8773ea523d6a7bf04dc74565de69b899bc2ff32'
'049240975cd2f1c88fbe7deb28af14d4ec7d2640495f7ca8980d873bb710cc97')
prepare() {
cd glib-$pkgver
patch -Rp1 -i ../revert-warn-glib-compile-schemas.patch
}
build() {
cd glib-$pkgver
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --libdir=/usr/lib \
--sysconfdir=/etc \
--with-pcre=system \
--disable-fam
make
}
check() {
cd glib-$pkgver
#make -k check || :
}
package_glib2() {
depends=('pcre' 'libffi')
optdepends=('python2: for gdbus-codegen and gtester-report'
'elfutils: gresource inspection tool')
options=('!docs' '!libtool' '!emptydirs')
license=('LGPL')
cd glib-$pkgver
make completiondir=/usr/share/bash-completion/completions DESTDIR="$pkgdir" install
for _i in "$pkgdir/usr/share/bash-completion/completions/"*; do
chmod -x "$_i"
done
# Our gdb does not ship the required python modules, so remove it
rm -rf "$pkgdir/usr/share/gdb/"
}
package_glib2-docs() {
pkgdesc="Documentation for glib2"
conflicts=('gobject2-docs')
replaces=('gobject2-docs')
license=('custom')
options=('docs' '!emptydirs')
cd glib-$pkgver/docs
make DESTDIR="${pkgdir}" install
install -m755 -d "${pkgdir}/usr/share/licenses/glib2-docs"
install -m644 reference/COPYING "${pkgdir}/usr/share/licenses/glib2-docs/"
rm -rf "${pkgdir}/usr/share/man"
}
|
