blob: 9a79b47ed1ea8dc017804063a43557875fe87af3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 172097 2012-11-28 10:31:12Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=glib2
pkgver=2.34.3
pkgrel=1
pkgdesc="Common C routines used by GTK+ and other libs"
url="http://www.gtk.org/"
arch=(i686 x86_64)
license=('LGPL')
depends=('pcre' 'libffi')
makedepends=('pkg-config' 'python2' 'libxslt' 'docbook-xml')
optdepends=('python2: for gdbus-codegen')
options=('!libtool' '!docs' '!emptydirs')
source=(http://ftp.gnome.org/pub/GNOME/sources/glib/${pkgver%.*}/glib-$pkgver.tar.xz
revert-warn-glib-compile-schemas.patch)
sha256sums=('855fcbf87cb93065b488358e351774d8a39177281023bae58c286f41612658a7'
'049240975cd2f1c88fbe7deb28af14d4ec7d2640495f7ca8980d873bb710cc97')
build() {
cd glib-$pkgver
patch -Rp1 -i "$srcdir/revert-warn-glib-compile-schemas.patch"
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --libdir=/usr/lib \
--sysconfdir=/etc \
--with-pcre=system \
--disable-fam
make
}
package() {
cd glib-$pkgver
make completiondir=/usr/share/bash-completion/completions DESTDIR="$pkgdir" install
for _i in "$pkgdir/usr/share/bash-completion/completions/"*; do
chmod -x "$_i"
done
sed -i "s|#!/usr/bin/env python|#!/usr/bin/env python2|" "$pkgdir"/usr/bin/gdbus-codegen
}
|
