blob: 7f84851d2238b2fc28fb5306e88b15aad093a8c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# $Id: PKGBUILD 193522 2013-08-21 22:25:01Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
pkgname=gnupg
pkgver=2.0.21
pkgrel=1
pkgdesc='Complete and free implementation of the OpenPGP standard'
url='http://www.gnupg.org/'
license=('GPL')
arch=('i686' 'x86_64')
optdepends=('curl: gpg2keys_curl'
'libldap: gpg2keys_ldap'
'libusb-compat: scdaemon')
makedepends=('curl' 'libldap' 'libusb-compat')
depends=('bzip2' 'libksba' 'libgcrypt' 'pth' 'libassuan' 'readline' 'pinentry' 'dirmngr')
source=("ftp://ftp.gnupg.org/gcrypt/${pkgname}/${pkgname}-${pkgver}.tar.bz2"{,.sig}
'protect-tool-env.patch')
sha1sums=('5ba8cce72eb4fd1a3ac1a282d25d7c7b90d3bf26' 'SKIP'
'2ec97ba55ae47ff0d63bc813b8c64cb79cef11db')
install=install
conflicts=('gnupg2')
provides=("gnupg2=${pkgver}")
replaces=('gnupg2')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../protect-tool-env.patch # FS#31900
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--libexecdir=/usr/lib/gnupg \
--enable-maintainer-mode \
--enable-symcryptrun \
--enable-gpgtar \
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make check
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
ln -s gpg2 "${pkgdir}"/usr/bin/gpg
ln -s gpgv2 "${pkgdir}"/usr/bin/gpgv
ln -s gpg2.1.gz "${pkgdir}"/usr/share/man/man1/gpg.1.gz
rm "${pkgdir}/usr/share/gnupg/com-certs.pem" # FS#33059
}
|
