blob: cf727defa5d46261836e14ff47b1bd1920fbae64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 178100 2013-02-16 08:46:34Z allan $
# Maintainer:
pkgname=groff
pkgver=1.22.2
pkgrel=2
pkgdesc="GNU troff text-formatting system"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/groff/groff.html"
license=('GPL')
groups=('base-devel')
depends=('perl' 'gcc-libs')
makedepends=('netpbm' 'psutils' 'ghostscript')
optdepends=('netpbm: for use together with man -H command interaction in browsers'
'psutils: for use together with man -H command interaction in browsers')
source=(ftp://ftp.gnu.org/gnu/groff/groff-$pkgver.tar.gz{,.sig}
site.tmac)
options=('!docs' '!emptydirs')
install=groff.install
md5sums=('9f4cd592a5efc7e36481d8d8d8af6d16'
'65207deb0a9b54324cb947f25ec9164f'
'a1fedafd7863b37968d32ad9ae1d8c13')
build() {
cd $srcdir/$pkgname-$pkgver
./configure --prefix=/usr --without-x
make
}
check() {
cd $srcdir/$pkgname-$pkgver
make check
}
package() {
cd $srcdir/$pkgname-$pkgver
make DESTDIR=$pkgdir install
# add compatibility symlinks
ln -s eqn $pkgdir/usr/bin/geqn
ln -s tbl $pkgdir/usr/bin/gtbl
ln -s soelim $pkgdir/usr/bin/zsoelim
# FS33760 - TERMCAP variables not followed
# TODO: everyone is doing this - find out why upstream does not...
cat $srcdir/site.tmac >> \
$pkgdir/usr/share/groff/site-tmac/man.local
cat $srcdir/site.tmac >> \
$pkgdir/usr/share/groff/site-tmac/mdoc.local
}
|
