blob: bce4b994cee304b521e9a63206ccad8d8ba3e653 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 196308 2013-10-11 09:58:13Z tpowa $
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
pkgname=kbd
pkgver=2.0.0
pkgrel=2
pkgdesc="Keytable files and keyboard utilities"
arch=('i686' 'x86_64')
url="http://www.kbd-project.org"
license=('GPL')
depends=('glibc' 'pam')
makedepends=('check')
source=(ftp://ftp.altlinux.org/pub/people/legion/kbd/${pkgname}-${pkgver}.tar.gz
'fix-dvorak-es.patch'
'fix-euro2.patch'
'fix-alt_is_meta.patch'
'merge-fullline_singleline.patch')
provides=('vlock')
conflicts=('vlock')
replaces=('vlock')
md5sums=('5ba259a0b2464196f6488a72070a3d60'
'998957c4f815347dcc874c4d7555dc66'
'd869200acbc0aab6a9cafa43cb140d4e'
'91de90cde763c7f704027c2837360098'
'b21e24509ea9db206971ce8a02dfc46f')
prepare() {
cd ${srcdir}/${pkgname}-${pkgver}
# rename keymap files with the same names
# this is needed because when only name of keymap is specified
# loadkeys loads the first keymap it can find, which is bad (see FS#13837)
# this should be removed when upstream adopts the change
mv data/keymaps/i386/qwertz/cz{,-qwertz}.map
mv data/keymaps/i386/olpc/es{,-olpc}.map
mv data/keymaps/i386/olpc/pt{,-olpc}.map
mv data/keymaps/i386/dvorak/no{,-dvorak}.map
mv data/keymaps/i386/fgGIod/trf{,-fgGIod}.map
mv data/keymaps/i386/colemak/{en-latin9,colemak}.map
# fix es-dvorak #33662
patch -Np1 -i ../fix-dvorak-es.patch
# fix euro2 #28213
patch -Np1 -i ../fix-euro2.patch
# fix #36689
patch -Np1 -i ../fix-alt_is_meta.patch
patch -Np1 -i ../merge-fullline_singleline.patch
}
build() {
cd ${srcdir}/${pkgname}-${pkgver}
./configure --prefix=/usr --datadir=/usr/share/kbd --mandir=/usr/share/man
make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes DESTDIR=${pkgdir} install
}
|
