blob: 5de4b2d70478cd5726b0523e85e5dc104daa9a6b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 179845 2013-03-10 12:44:09Z bluewind $
# Maintainer: Pierre Schmitz <pierre@archlinux.de>
pkgname=logrotate
pkgver=3.8.3
pkgrel=1
pkgdesc="Rotates system logs automatically"
arch=('i686' 'x86_64' 'mips64el')
url="https://fedorahosted.org/logrotate/"
license=('GPL')
groups=('base')
depends=('popt' 'gzip' 'acl')
optdepends=('cron: scheduled log rotation')
backup=('etc/logrotate.conf')
source=("https://fedorahosted.org/releases/l/o/logrotate/logrotate-${pkgver}.tar.gz"
'noasprintf.patch'
'paths.patch'
'logrotate.conf'
'logrotate.cron.daily')
md5sums=('df67c8bda9139131d919931da443794d'
'cd76976b5ce37d328b452c806b55a015'
'e76526bcd6fc33c9d921e1cb1eff1ffb'
'86209d257c8b8bc0ae34d6f6ef057c0f'
'aa8ac8283908b6114483a293adcb650f')
build() {
cd "$srcdir/${pkgname}-${pkgver}"
patch -p0 -i "$srcdir/noasprintf.patch"
patch -p0 -i "$srcdir/paths.patch"
make WITH_ACL=yes RPM_OPT_FLAGS="$CFLAGS" EXTRA_LDFLAGS="$LDFLAGS"
}
check() {
cd "$srcdir/${pkgname}-${pkgver}"
make test
}
package() {
cd "$srcdir/${pkgname}-${pkgver}"
make PREFIX="$pkgdir" MANDIR="/usr/share/man" install
install -Dm644 "$srcdir/logrotate.conf" "$pkgdir/etc/logrotate.conf"
install -Dm744 "$srcdir/logrotate.cron.daily" "$pkgdir/etc/cron.daily/logrotate"
}
|
