blob: 4f2889baf0886fe532d86930d0d360cd0c1ce538 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 100405 2010-11-23 12:35:30Z stephane $
# Contributor: Low Kian Seong <fastmail_low@speedymail.org>
# Maintainer: dorphell <dorphell@archlinux.org>
pkgname=lzo2
pkgver=2.04
pkgrel=1
pkgdesc="Portable lossless data compression library"
arch=('i686' 'x86_64')
url="http://www.oberhumer.com/opensource/lzo"
license=('GPL')
depends=('glibc')
source=(http://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)
options=(!libtool)
sha1sums=('f5bf5c7ae4116e60513e5788d156ef78946677e7')
build() {
cd "${srcdir}/lzo-${pkgver}"
./configure --prefix=/usr --enable-shared
make
# build minilzo
gcc $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
gcc -g -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
}
package() {
cd "${srcdir}/lzo-${pkgver}"
make DESTDIR=${pkgdir} install
# install minilzo
install -m 755 libminilzo.so.0 ${pkgdir}/usr/lib
install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
cd ${pkgdir}/usr/lib
ln -s libminilzo.so.0 libminilzo.so
}
|
