blob: b6050d66d65c6f4eeebaea19717274b101b4673b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 144465 2011-12-06 10:57:39Z dreisner $
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>
pkgname=module-init-tools
pkgver=3.16
pkgrel=3
pkgdesc="Utilities needed by Linux systems for managing loadable kernel modules"
arch=('i686' 'x86_64')
url="https://modules.wiki.kernel.org"
license=('GPL')
depends=('glibc')
makedepends=('docbook2x')
backup=('etc/modprobe.d/modprobe.conf'
'etc/depmod.d/depmod.conf')
source=("http://www.kernel.org/pub/linux/utils/kernel/$pkgname/$pkgname-$pkgver.tar.bz2"
modprobe.conf
depmod.conf
docfix.patch)
md5sums=('bc44832c6e41707b8447e2847d2019f5'
'325657db471b3190f685e5a89c9b90e3'
'4b8cbcbc54b9029c99fd730e257d4436'
'4320d19902ded43bed55c804b065cdc7')
build() {
cd "$srcdir/$pkgname-$pkgver"
# fix headers in SGML manpage sources and an XML typo
patch -Np0 < "$srcdir/docfix.patch"
./configure --prefix=/usr --exec-prefix=/ --enable-zlib
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR=$pkgdir install
# extra modprobe.d and depmod.d conf dirs
install -dm755 "$pkgdir/lib/modprobe.d" "$pkgdir/etc/depmod.d"
# Install custom depmod config to allow searching extramodules/
install -Dm644 "$srcdir/depmod.conf" "$pkgdir/etc/depmod.d/depmod.conf"
# Install our custom (empty) modprobe.conf
install -Dm644 "$srcdir/modprobe.conf" "$pkgdir/etc/modprobe.d/modprobe.conf"
}
|
