blob: ed0c13f86b1b42823c46a17d5b6de710441b1aa0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 197154 2013-10-23 13:04:19Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
pkgname=pcre
pkgver=8.33
pkgrel=2
pkgdesc="A library that implements Perl 5-style regular expressions"
arch=('i686' 'x86_64')
url="http://www.pcre.org/"
license=('BSD')
depends=('gcc-libs')
source=(ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/${pkgname}-${pkgver}.tar.bz2{,.sig})
md5sums=('21514018448ac10062ece7a668fca949'
'SKIP')
build() {
cd "${srcdir}"/${pkgname}-${pkgver}
./configure --prefix=/usr \
--enable-pcre16 --enable-pcre32 --enable-jit \
--enable-utf --enable-unicode-properties
make
}
check() {
cd "${srcdir}"/${pkgname}-${pkgver}
make -j1 check
}
package() {
cd "${srcdir}"/${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
install -Dm644 LICENCE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|
