blob: c08ca8b5be0c48951e2f85b36c6a3e075d9597f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 188912 2013-06-25 10:40:52Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>
pkgname=procps-ng
pkgver=3.3.8
pkgrel=2
pkgdesc='Utilities for monitoring your system and its processes'
url='http://gitorious.org/procps'
license=('GPL' 'LGPL')
arch=('i686' 'x86_64')
groups=('base')
depends=('ncurses')
backup=('etc/sysctl.conf')
source=("${pkgname}-${pkgver}.tar.gz::http://gitorious.org/procps/procps/archive-tarball/v${pkgver}"
'sysctl.conf')
sha1sums=('63aed46ba4b5b05698beb25d2aa3eee6779d7f45'
'bc4e929a0ddcdcd627e8d15d30abcf185aa33fab')
conflicts=('procps')
provides=('procps')
replaces=('procps')
options=('!libtool')
prepare() {
cd "${srcdir}/procps-procps"
echo ${pkgver} > .tarball-version
./autogen.sh
}
build() {
cd "${srcdir}/procps-procps"
./configure \
--prefix=/usr \
--exec-prefix=/ \
--sysconfdir=/etc \
--libdir=/usr/lib \
--bindir=/usr/bin \
--sbindir=/usr/bin \
--disable-static
make
}
package() {
cd "${srcdir}/procps-procps"
make DESTDIR="${pkgdir}" install
install -D -m644 ../sysctl.conf "${pkgdir}/etc/sysctl.conf"
# provided by util-linux
rm "${pkgdir}/usr/bin/kill"
rm "${pkgdir}/usr/share/man/man1/kill.1"
}
|
