blob: 0e273054345aa6e413e2d555fcd208624643c400 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 196010 2013-10-07 11:50:21Z jgc $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=aisleriot
pkgver=3.10.0
pkgrel=1
pkgdesc="A collection of patience games written in guile scheme"
arch=(i686 x86_64 mips64el)
license=(GPL)
url="http://www.gnome.org"
groups=('gnome-extra')
depends=(guile gtk3 librsvg libcanberra gconf hicolor-icon-theme dconf)
makedepends=(intltool itstool docbook-xsl yelp-tools desktop-file-utils)
optdepends=('libkdegames: KDE card sets'
'pysolfc: PySol card sets'
'pysolfc-cardsets: PySol card sets')
options=('!emptydirs' '!libtool')
install=aisleriot.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('2b96e73fa2e3c75afc27b2a572c4175943fbaac015824a6f49c41bf479b26e02')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib --disable-static \
--with-card-theme-formats=all \
--with-kde-card-theme-path=/usr/share/apps/carddecks \
--with-pysol-card-theme-path=/usr/share/PySolFC
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1
install -m755 -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" \
--domain aisleriot "$pkgdir"/etc/gconf/schemas/*.schemas
rm -f "$pkgdir"/etc/gconf/schemas/*.schemas
}
|
