blob: 59b2238d72a2f0d9a37e21896aac7c34c7ff689e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 163142 2012-07-08 09:30:27Z ibiru $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Daniel Ehlers <danielehlers@mindeye.net>
pkgname=alsa-plugins
pkgver=1.0.25
pkgrel=2
pkgdesc="Extra alsa plugins"
arch=(i686 x86_64 'mips64el')
url="http://www.alsa-project.org"
license=(GPL)
depends=(alsa-lib)
makedepends=(libpulse jack ffmpeg)
optdepends=('libpulse: PulseAudio plugin'
'jack: Jack plugin'
'ffmpeg: libavcodec resampling plugin'
'libsamplerate: libsamplerate resampling plugin'
'speex: libspeexdsp resampling plugin')
options=('!libtool')
source=("ftp://ftp.alsa-project.org/pub/plugins/$pkgname-$pkgver.tar.bz2"
alsa-plugins-1.0.25-ffmpeg-0.11-renamed-CH_LAYOUT-defs-v2.patch
alsa-plugins-1.0.25-ffmpeg-0.11-obsolete-avcodec_init.patch
gcc-4.7.patch)
md5sums=('038c023eaa51171f018fbf7141255185'
'50d9adcda20756d063e676a563c201d9'
'697c6275f678d86ded2e5092d8a154c9'
'3b76ed6c9b59eccca0b33a731641350d')
build() {
cd $pkgname-$pkgver
patch -Np1 -i ../alsa-plugins-1.0.25-ffmpeg-0.11-renamed-CH_LAYOUT-defs-v2.patch
patch -Np1 -i ../alsa-plugins-1.0.25-ffmpeg-0.11-obsolete-avcodec_init.patch
patch -Np1 -i "$srcdir/gcc-4.7.patch"
./configure --prefix=/usr
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
install -d "$pkgdir/usr/share/doc/$pkgname"
install -m644 doc/README* doc/*.txt "$pkgdir/usr/share/doc/$pkgname/"
}
|
