blob: e9e5fadfb62d780daff4634d50465a5bd94325ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# $Id: PKGBUILD 183314 2013-04-21 22:06:32Z heftig $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Harley Laue <losinggeneration@yahoo.com>
pkgbase=anjuta
pkgname=('libanjuta' 'anjuta')
pkgver=3.8.1
pkgrel=1
pkgdesc="GNOME Integrated Development Environment (IDE)"
arch=(i686 x86_64)
license=(GPL)
makedepends=(gdl vte3 autogen devhelp glade libgda subversion gnome-icon-theme vala dconf
gtk-doc yelp-tools gnome-common intltool gobject-introspection itstool gjs
python)
url="http://www.anjuta.org/"
options=('!libtool' '!emptydirs')
source=(ftp://ftp.gnome.org/pub/gnome/sources/$pkgbase/${pkgver%.*}/$pkgbase-$pkgver.tar.xz
fix-compile-error.patch anjuta-glade.xml.diff)
sha256sums=('ef5d8a5032d4c2025e1870bef044fa025f01096a86f8f226eb178688a960c5b9'
'd072af4c1c52ce65f84026b83baa642a9bcfa06b10913b356b5cd99d98931b1d'
'e480c41a92198c9158f7d66f248b83464e6d0745d5756dae581b204d5439cc4d')
build() {
cd "$pkgbase-$pkgver"
patch -Np1 -i ../fix-compile-error.patch
patch -Np1 -i ../anjuta-glade.xml.diff
# Bump vala version
sed -i '/vala/s/-0\.18/-0.20/' configure.ac
./autogen.sh --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --enable-glade-catalog --enable-compile-warnings=minimum
make
}
package_libanjuta(){
pkgdesc="Anjuta runtime library"
depends=(gdl)
conflicts=('anjuta<3.4.4')
cd "$pkgbase-$pkgver/libanjuta"
# j1: Race during linking
make -j1 DESTDIR="$pkgdir" install
}
package_anjuta(){
pkgdesc="GNOME Integrated Development Environment (IDE)"
depends=(libanjuta vte3 autogen devhelp glade libgda subversion gnome-icon-theme vala dconf)
groups=('gnome-extra')
install=anjuta.install
cd "$pkgbase-$pkgver"
make -j1 DESTDIR="$pkgdir" install
cd libanjuta
make -j1 DESTDIR="$pkgdir" uninstall
}
|
