blob: d940edfb730c2a55ced592dd724d4822cdc50bf4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 171315 2012-11-17 05:25:07Z eric $
# Maintainer: Jürgen Hötzel <juergen@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
# Contributor: Kevin Piche <kevin@archlinux.org>
pkgname=bigloo
_pkgver=3.9a
pkgver=${_pkgver/-/_}
pkgrel=1
pkgdesc="Fast scheme compiler"
arch=('i686' 'x86_64')
url="http://www-sop.inria.fr/mimosa/fp/Bigloo/"
license=('GPL' 'LGPL')
depends=()
makedepends=('java-environment' 'emacs' 'zip' 'sqlite' 'alsa-lib' 'flac' 'avahi')
optdepends=('emacs' 'java-environment' 'zip' 'sqlite' 'alsa-lib' 'flac' 'avahi')
options=('!makeflags')
install=bigloo.install
source=(ftp://ftp-sop.inria.fr/indes/fp/Bigloo/${pkgname}${_pkgver}.tar.gz)
md5sums=('7091f6f54cb5f63768a8152085d1bd02')
build() {
cd "${srcdir}/${pkgname}${_pkgver}"
./configure --prefix=/usr \
--enable-ssl \
--enable-sqlite \
--enable-avahi \
--enable-flac \
--disable-gstreamer \
--mandir=/usr/share/man \
--infodir=/usr/share/info \
--docdir=/usr/share/doc/bigloo \
--jvm=yes
make build compile-bee
}
check() {
cd "${srcdir}/${pkgname}${_pkgver}"
make test
}
package() {
cd "${srcdir}/${pkgname}${_pkgver}"
make DESTDIR="${pkgdir}" install install-bee
make -C manuals DESTDIR="${pkgdir}" install-bee
chmod 644 "${pkgdir}"/usr/lib/bigloo/${_pkgver%-*}/*.a
}
|
