1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 183180 2013-04-18 13:14:56Z dreisner $
# Contributor: FUBAR <mrfubar@gmail.com>
# Contributor: simo <simo@archlinux.org>
# Contributor: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Maintainer: Dave Reisner <dreisner@archlinux.org>
pkgname=bitlbee
pkgver=3.2
pkgrel=2
pkgdesc='Brings instant messaging (XMPP, MSN, Yahoo!, AIM, ICQ, Twitter) to IRC'
url='http://www.bitlbee.org/'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('gnutls' 'glib2')
makedepends=('asciidoc' 'libotr3')
optdepends=('libotr3: for OTR encryption support'
'xinetd: to run bitlbee through xinetd')
source=("http://get.bitlbee.org/src/${pkgname}-${pkgver}.tar.gz"
'xinetd'
'bitlbee.tmpfiles')
sha1sums=('21e17f082c776566429603b1e8c966983a75ac9e'
'5e0af27ba9cc4fe455e3381c75fc49a9326e2f17'
'3695ed2fe22436c4d0fc3ead829f7d1f89bc491c')
backup=('etc/bitlbee/bitlbee.conf'
'etc/bitlbee/motd.txt'
'etc/xinetd.d/bitlbee')
install=bitlbee.install
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--etcdir=/etc/bitlbee \
--pidfile=/run/bitlbee/bitlbee.pid \
--ipcsocket=/run/bitlbee/bitlbee.sock \
--systemdsystemunitdir=/usr/lib/systemd/system \
--ssl=gnutls \
--strip=0 \
--otr=plugin
# hacky: build against libotr3
sed -i 's,^OTRFLAGS=.*,OTRFLAGS=-lotr3,' Makefile.settings
sed -i 's,#include.*libotr,&3,' otr.h
make
}
package() {
make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev}
install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
install -Dm644 "$srcdir/xinetd" "$pkgdir/etc/xinetd.d/bitlbee"
install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
}
|
