blob: 8c75eecd0d2a0739213e16d8733451d04a83b405 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# $Id: PKGBUILD 155739 2012-04-06 00:05:49Z tomegun $
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>
pkgname=bluez
pkgver=4.99
pkgrel=2
pkgdesc="Libraries and tools for the Bluetooth protocol stack"
url="http://www.bluez.org/"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL2')
depends=('dbus-core' 'python2' 'udev')
makedepends=('gstreamer0.10-base' 'libusb-compat' 'libsndfile')
optdepends=("gstreamer0.10-base: bluetooth GStreamer support"
"alsa-lib: Audio bluetooth devices support"
"dbus-python: to run bluez-simple-agent"
"pygobject: to run bluez-simple-agent"
"libusb-compat: USB adapters support"
"cups: CUPS backend")
conflicts=('bluez-libs' 'bluez-utils')
provides=('bluez-libs' 'bluez-utils')
replaces=('bluez-libs' 'bluez-utils')
options=('!libtool')
backup=(etc/bluetooth/{main,rfcomm,audio,network,input,serial}.conf
'etc/conf.d/bluetooth' 'etc/dbus-1/system.d/bluetooth.conf')
source=("http://www.kernel.org/pub/linux/bluetooth/${pkgname}-${pkgver}.tar.bz2"
'bluetooth.conf.d'
'rc.bluetooth')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/lib \
--enable-gstreamer \
--enable-alsa \
--enable-usb \
--enable-tools \
--enable-bccmd \
--enable-dfutool \
--enable-hid2hci \
--enable-hidd \
--enable-pand \
--enable-dund \
--enable-cups \
--enable-wiimote \
--disable-test
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
install -Dm755 ${srcdir}/rc.bluetooth ${pkgdir}/etc/rc.d/bluetooth
install -d ${pkgdir}/etc/bluetooth
install -m644 network/network.conf \
input/input.conf \
audio/audio.conf \
serial/serial.conf \
${pkgdir}/etc/bluetooth/
install -Dm644 ${srcdir}/bluetooth.conf.d \
${pkgdir}/etc/conf.d/bluetooth
# FS#27630
install -Dm755 test/simple-agent "${pkgdir}"/usr/bin/bluez-simple-agent
install -Dm755 test/test-device "${pkgdir}"/usr/bin/bluez-test-device
install -Dm755 test/test-input "${pkgdir}"/usr/bin/bluez-test-input
sed -i 's#/usr/bin/python#/usr/bin/python2#' \
"${pkgdir}"/usr/bin/bluez-simple-agent \
"${pkgdir}"/usr/bin/bluez-test-device \
"${pkgdir}"/usr/bin/bluez-test-input
# http://mailman.archlinux.org/pipermail/arch-general/2011-April/019787.html
rm "${pkgdir}"/usr/lib/udev/rules.d/97-bluetooth.rules
}
md5sums=('2387053eb5a7b02f37df4871df022a02'
'7412982b440f29fa7f76a41a87fef985'
'8f9498707f809506928b2e480d3b6789')
|
