blob: 9401392ed2a54d9c233532c05006591ee6a4b8d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 196019 2013-10-07 11:50:33Z jgc $
# Maintainer: Allan McRae <allan@archlinux.org>
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>
pkgname=brasero
pkgver=3.8.0
pkgrel=3
pkgdesc="A disc burning application for Gnome"
arch=('i686' 'x86_64')
url="http://www.gnome.org/projects/brasero"
license=('GPL')
options=('!libtool' '!emptydirs')
depends=('gtk3' 'gst-plugins-good' 'totem-plparser' 'cdrkit' 'cdrdao' 'desktop-file-utils' 'hicolor-icon-theme' 'shared-mime-info' 'libcanberra' 'dvd+rw-tools' 'dconf' 'libsm' 'libtracker-sparql' 'libnotify')
makedepends=('gtk-doc' 'yelp-tools' 'gnome-common' 'intltool' 'libburn' 'libisofs' 'libnautilus-extension' 'gobject-introspection' 'gconf' 'itstool' 'docbook-xsl')
optdepends=('libburn: alternative back-end'
'libisofs: libburn back-end'
'dvdauthor: video project'
'vcdimager: video project')
replaces=('nautilus-cd-burner')
install=brasero.install
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
bug655513.patch)
sha256sums=('d98a368a6129e50681e8243c5e0833c32cca699bd50b839c6a551d52b396bce4'
'3e774040c570881fe120af7c250a91e8a69331289490c823feed87c4d00f98fb')
prepare() {
cd "$pkgname-$pkgver"
# Update tracker dep
sed -i '/tracker/s/0\.14/0.16/' configure.ac
# Fix infinite loop after cancelling the burn image dialog
patch -Np1 -i ../bug655513.patch
}
build() {
cd "$pkgname-$pkgver"
autoreconf -f -v -i
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-caches \
--disable-schemas-compile
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR=$pkgdir install
}
|
