extra/claws-mail-extra-plugins/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# $Id: PKGBUILD 160463 2012-06-02 10:25:44Z bluewind $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Mildred <mildred593 at online dot fr>

pkgname=claws-mail-extra-plugins
pkgver=3.8.0
pkgrel=3
pkgdesc="Extra plugins for claws-mail"
url="http://www.claws-mail.org/plugins.php?branch=EXT"
license=('GPL3')
arch=('i686' 'x86_64')
depends=('claws-mail>=3.8.0')
makedepends=('make' 'bc' 'perl>=5.16.0' 'libgtkhtml>=2.11.1-2' 'libnotify>=0.7'
             'libxml2>=2.7.6' 'curl>=7.19.7' 'libytnef>=1.5-2' 'libwebkit>=1.6.1'
             'pygtk>=2.16.0' 'libsoup-gnome' 'libcanberra' 'libgdata')
optdepends=('libgtkhtml: for gtkhtml2_viewer plugin'
            'perl: for perl plugin'
            'libnotify: for notification plugin'
            'libcanberra: for notification plugin'
            'dbus-core: for notification plugin'
            'libxml2: for gtkhtml2_viewer and rssyl plugins'
            'curl: for gtkhtml2_viewer, vcalendar, rssyl and spamreport plugins'
            'libarchive: for archive plugin'
            'libytnef: for tnef_parse plugin'
            'libwebkit: for the fancy webkit html plugin'
            'libsoup-gnome: for the fancy webkit html plugin'
            'python2: for python plugin'
	    'libgdata: for gdata plugin')
conflicts=('claws-gtkhtml2_viewer' 'claws-mail-acpinotifier-plugin'
           'sylpheed-claws-gtkhtml2-plugin' 'sylpheed-claws-rssyl-plugin'
           'sylpheed-claws-extra-plugins' 'claws-tnef-plugin'
           'claws-webkit-plugin-svn' 'claws-mayflower-plugin-svn')
replaces=('sylpheed-claws-extra-plugins')
options=('!libtool' '!strip')
source=(http://downloads.sourceforge.net/project/sylpheed-claws/extra%20plugins/$pkgver/claws-mail-extra-plugins-$pkgver.tar.bz2)
md5sums=('4776f6e0357a694f384349ac73b6da52')

build() {
  cd "$srcdir/claws-mail-extra-plugins-$pkgver"

  # fix for python2
  export PYTHON="/usr/bin/python2"

  # fix gdata plugin build
  sed -i -e "s:libgdata\ <\ 0.9.0:libgdata\ <\ 0.11.0:g" gdata_plugin-0.3/configure
 
  for dir in */; do
    [[ $dir != geolocation_plugin-* ]] && (
      cd $dir

      ./configure --prefix=/usr --disable-static
      make
    )
  done
}

package() {
  cd "$srcdir/claws-mail-extra-plugins-$pkgver"
  for dir in */; do
    [[ $dir != geolocation_plugin-* ]] && 
      make -C $dir DESTDIR="$pkgdir" install
  done

  # fix fileconflict with libical, #11485
  rm -f "$pkgdir/usr/include/ical.h"
}