blob: c471fddf7ad3c1a6cdc238523fb5b507a105d0c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 145779 2011-12-31 11:08:34Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgname=cmake
pkgver=2.8.7
pkgrel=1
pkgdesc="A cross-platform open-source make system"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.cmake.org"
depends=('curl' 'libarchive' 'shared-mime-info')
makedepends=('qt')
optdepends=('qt: cmake-gui')
install="${pkgname}.install"
source=("http://www.cmake.org/files/v2.8/${pkgname}-${pkgver}.tar.gz")
md5sums=('e1b237aeaed880f65dec9c20602452f6')
build() {
cd "${srcdir}"/${pkgname}-${pkgver}
./bootstrap --prefix=/usr \
--mandir=/share/man \
--docdir=/share/doc/cmake \
--system-libs \
--qt-gui \
--parallel=2
make
}
package() {
cd "${srcdir}"/${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
vimpath="$pkgdir/usr/share/vim/vimfiles"
install -Dm644 Docs/cmake-indent.vim ${vimpath}/indent/cmake-indent.vim
install -Dm644 Docs/cmake-syntax.vim ${vimpath}/syntax/cmake-syntax.vim
install -Dm644 Docs/cmake-mode.el ${pkgdir}/usr/share/emacs/site-lisp/cmake-mode.el
install -Dm644 Copyright.txt ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}
|
