blob: 81cae317128d7d0a6b3c1806d367ab8abea65d1c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 200685 2013-12-02 11:59:05Z svenstaro $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgname=cmake
pkgver=2.8.12.1
pkgrel=3
pkgdesc="A cross-platform open-source make system"
arch=('i686' 'x86_64')
url="http://www.cmake.org/"
license=('custom')
depends=('curl' 'libarchive' 'shared-mime-info')
makedepends=('qt4' 'emacs')
optdepends=('qt4: cmake-gui')
install="${pkgname}.install"
source=("http://www.cmake.org/files/v2.8/${pkgname}-${pkgver}.tar.gz"
"findfreetype.patch")
md5sums=('9d38cd4e2c94c3cea97d0e2924814acc'
'90321de1d9d46cd8d6609d0509dbd7b0')
build() {
cd ${pkgname}-${pkgver}
patch -Np1 < ${srcdir}/findfreetype.patch
./bootstrap --prefix=/usr \
--mandir=/share/man \
--docdir=/share/doc/cmake \
--system-libs \
--qt-gui \
--parallel=$(/usr/bin/getconf _NPROCESSORS_ONLN)
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
vimpath="${pkgdir}/usr/share/vim/vimfiles"
install -Dm644 Docs/cmake-indent.vim "${vimpath}"/indent/cmake-indent.vim
install -Dm644 Docs/cmake-syntax.vim "${vimpath}"/syntax/cmake-syntax.vim
install -Dm644 Docs/cmake-mode.el \
"${pkgdir}"/usr/share/emacs/site-lisp/cmake-mode.el
emacs -batch -f batch-byte-compile "${pkgdir}"/usr/share/emacs/site-lisp/cmake-mode.el
install -Dm644 Copyright.txt \
"${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|
