blob: 3554491668a723ecac52b4cb6f75924165fa2456 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 120673 2011-04-25 22:55:12Z eric $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
pkgname=cmus
pkgver=2.4.0
pkgrel=1
pkgdesc="A very feature-rich ncurses-based music player"
arch=('i686' 'x86_64' 'mips64el')
url="http://cmus.sourceforge.net/"
license=('GPL')
depends=('ncurses')
makedepends=('libao' 'libmpcdec' 'ffmpeg' 'flac' 'libmad' 'faad2' 'libmodplug' 'libvorbis' 'libpulse' 'wavpack')
optdepends=('alsa-lib: for ALSA output plugin support'
'libao: for AO output plugin support'
'libpulse: for PulseAudio output plugin support'
'ffmpeg: for ffmpeg input plugin support'
'libmodplug: for modplug input plugin support'
'faad2: for input AAC plugin support'
'libmad: for mp3 input plugin support'
'libmpcdec: for musepack input plugin support'
'wavpack: for wavpack input plugin support'
'libvorbis: for vorbis input plugin support'
'flac: for flac input plugin support')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-v$pkgver.tar.bz2")
md5sums=('0c5a9f4032e632e5f6b6a49f53df1e7e')
sha1sums=('cbd80d1ff12be5dbf9a3b8b6494381f8b3073761')
build() {
cd "$srcdir/$pkgname-v$pkgver"
sed -i 's|ffmpeg/avcodec.h|libavcodec/avcodec.h|' configure ffmpeg.c
sed -i 's|ffmpeg/avformat.h|libavformat/avformat.h|' ffmpeg.c
sed -i 's|ffmpeg/avio.h|libavformat/avio.h|' ffmpeg.c
./configure prefix=/usr CONFIG_ARTS=n
make
}
package() {
cd "$srcdir/$pkgname-v$pkgver"
make DESTDIR="$pkgdir" install
install -D -m 644 contrib/_cmus "$pkgdir/usr/share/zsh/site-functions/_cmus"
}
|
