blob: a5dbb427c8a2ed43584fee0afe22b25af677d6c3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 165316 2012-08-15 13:47:42Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>
pkgbase=doxygen
pkgname=('doxygen' 'doxygen-docs')
pkgver=1.8.2
pkgrel=1
license=('GPL')
arch=(i686 x86_64 'mips64el')
url="http://www.doxygen.org/"
makedepends=('gcc-libs' 'flex' 'qt' 'texlive-core' 'ghostscript' 'texlive-latexextra')
source=(ftp://ftp.stack.nl/pub/users/dimitri/${pkgname}-${pkgver}.src.tar.gz)
md5sums=('6fa7baf995fa3f71cfc09e264ba88a83')
sha1sums=('7b88ade3989ce0f43f0fb2b2574436c4f1fa1c5a')
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
QTDIR=/usr ./configure --prefix /usr --with-doxywizard
make
}
package_doxygen() {
pkgdesc="A documentation system for C++, C, Java, IDL and PHP"
depends=('gcc-libs')
optdepends=('graphviz: for caller/callee graph generation'
'qt: for doxywizard')
cd "${srcdir}/${pkgbase}-${pkgver}"
make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install
}
package_doxygen-docs() {
pkgdesc="Developer documentation for doxygen"
cd "${srcdir}/${pkgbase}-${pkgver}"
# Needs fonts removed from our TeXLive.
sed -i -e 's;$(MAKE) -C latex;:;' \
-e 's;$(INSTTOOL) -m 644 latex/doxygen_manual.pdf $(DESTDIR)/$(DOCDIR);:;' \
Makefile
make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install_docs
}
|
