blob: a81bb963b0b33773f91bc9f955fc637e0bf9291a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 140851 2011-10-20 05:41:55Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=empathy
pkgver=3.2.1
pkgrel=1
pkgdesc="A GNOME instant messaging client using the Telepathy framework."
arch=('i686' 'x86_64')
url="http://live.gnome.org/Empathy"
license=('GPL2')
depends=('libpulse' 'clutter-gtk' 'clutter-gst' 'telepathy-mission-control' 'telepathy-logger' 'telepathy-farsight' 'telepathy-farstream' 'folks' 'gnome-keyring'
'libcanberra' 'iso-codes' 'networkmanager')
makedepends=('intltool' 'gnome-doc-utils' 'nautilus-sendto')
optdepends=('telepathy-gabble: XMPP/Jabber support'
'telepathy-butterfly: MSN support'
'telepathy-idle: IRC support'
'telepathy-salut: Link-local XMPP support'
'telepathy-sofiasip: SIP support'
'telepathy-haze: libpurple support')
options=('!libtool')
groups=('gnome-extra')
install=empathy.install
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/3.2/${pkgname}-${pkgver}.tar.xz)
sha256sums=('d50e9b0e31df0e8d137c120c61c5aeaaad06fb24bb208d105b186a01b3f1de0a')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/empathy \
--disable-static \
--disable-scrollkeeper \
--disable-schemas-compile
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
