blob: 3618a80f78b881db9bef3e78fbb8d25976104d6e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 181689 2013-04-04 05:04:01Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=fluxbox
pkgver=1.3.5
pkgrel=2
pkgdesc="A lightweight and highly-configurable window manager"
arch=('i686' 'x86_64')
url="http://www.fluxbox.org"
license=('MIT')
depends=('libxft' 'libxpm' 'libxinerama' 'libxrandr' 'gcc-libs' 'imlib2' 'fribidi')
optdepends=('xorg-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
options=('!makeflags')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.lzma \
fluxbox.desktop)
sha1sums=('495d82ca428949cc2bc85814898b49cf4624b7cb'
'f3f83b8ce84d79c2f8670ef687e0dd89ab0552b8')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr \
--enable-xft --enable-xinerama \
--enable-imlib2 --enable-nls
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
sed -i 's/@EXEEXT@//g' "${pkgdir}"/usr/{bin/fluxbox-generate_menu,share/fluxbox/menu}
install -D -m644 ../fluxbox.desktop "${pkgdir}/usr/share/xsessions/fluxbox.desktop"
install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
