blob: 6090afa89cedca78a3d1abcc6b8927841efcea70 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# $Id: PKGBUILD 203200 2014-01-05 09:58:03Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>
pkgname=fontforge
_pkgver=2.0.20140101
pkgver=${_pkgver##*.}
pkgrel=1
pkgdesc='Outline and bitmap font editor'
url='http://fontforge.sourceforge.net/'
arch=('i686' 'x86_64')
license=('BSD')
depends=('libxkbui' 'libxi' 'libxml2' 'pango' 'giflib' 'libtiff' 'python2' 'libspiro'
'libltdl' 'desktop-file-utils' 'gtk-update-icon-cache' 'hicolor-icon-theme')
source=("https://github.com/fontforge/fontforge/archive/${_pkgver}.tar.gz"
'http://fontforge.org/cidmaps.tgz')
sha1sums=('abce297e53e8b6ff6f08871e53d1eb0be5ab82e7'
'efbc7c9d3e95159f5600dc71f9cccb370e46bb94')
options=('!makeflags')
install=install
prepare() {
cd "${srcdir}/${pkgname}-${_pkgver}"
sed '/fontforge_package_name/s/^#//' -i configure.ac
./autogen.sh
}
build() {
cd "${srcdir}/${pkgname}-${_pkgver}"
export PYTHON=python2
./configure \
--prefix=/usr \
--mandir=/usr/share/man \
--enable-python-extension \
make
}
package() {
cd "${srcdir}/${pkgname}-${_pkgver}"
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}/usr/share/fontforge"
install -m644 ../Adobe-* "${pkgdir}/usr/share/fontforge"
install -d "${pkgdir}/usr/share/icons"
cp -a desktop/icons "${pkgdir}/usr/share/icons/hicolor"
rm -fr "${pkgdir}/usr/share/icons/hicolor/src"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 desktop/fontforge.desktop "${pkgdir}/usr/share/applications/fontforge.desktop"
}
|
