blob: b59505dbf17c12742cae8d12581fbc9a973fb675 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 186373 2013-05-26 09:24:23Z bluewind $
# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Brandon Niemczyk <maccorin@cfl.rr.com>
pkgname=frozen-bubble
_pkgver=2.2.1-beta1
pkgver=${_pkgver/-/}
pkgrel=5
pkgdesc="A game in which you throw colorful bubbles and build groups to destroy the bubbles"
arch=(i686 x86_64)
url="http://www.frozen-bubble.org"
license=(GPL2)
depends=(perl-sdl perl-ipc-system-simple perl-compress-bzip2 perl-file-which)
makedepends=(perl-file-slurp perl-locale-maketext-lexicon)
options=('!emptydirs')
source=(http://www.frozen-bubble.org/data/$pkgname-$_pkgver.tar.bz2 \
frozen-bubble.desktop)
md5sums=('825cc23ed806838b9d86de9982a5687a'
'01b10b77ba6ad856f5c199121c582272')
build() {
cd "$srcdir/$pkgname-$_pkgver"
unset CFLAGS
# install module in vendor directories
perl Build.PL installdirs=vendor
perl Build
}
check() {
cd "$srcdir/$pkgname-$_pkgver"
perl Build test
}
package() {
cd "$srcdir/$pkgname-$_pkgver"
perl Build install destdir="$pkgdir"
install -D -m644 share/icons/frozen-bubble-icon-64x64.png "$pkgdir/usr/share/pixmaps/frozen-bubble.png"
install -D -m644 "$srcdir/frozen-bubble.desktop" "$pkgdir/usr/share/applications/frozen-bubble.desktop"
}
|
