blob: cff2cff4e46aaf8f4561b1cbd0964ad503ec12e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 143589 2011-11-26 21:44:46Z heftig $
# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: Alexander Baldeck <alexander@archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
pkgname=ftgl
_pkgver=2.1.3-rc5
pkgver=${_pkgver/-/}
pkgrel=3
pkgdesc="OpenGL library to use arbitrary fonts"
arch=(i686 x86_64 'mips64el')
url="http://ftgl.wiki.sourceforge.net/"
license=(MIT)
depends=(freetype2 mesa)
makedepends=(doxygen glut)
options=('!libtool')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$_pkgver.tar.bz2")
md5sums=('c7879018cde844059495b3029b0b6503')
build() {
cd "$srcdir/$pkgname-${_pkgver/-/~}"
# Fix some missing libraries. Should be done in a different way.
sed -ri 's/.*_LDADD = .*/& $(GLUT_LIBS) $(GL_LIBS) -lm/' demo/Makefile.in
./configure --prefix=/usr --with-pic
make
}
package() {
cd "$srcdir/$pkgname-${_pkgver/-/~}"
make DESTDIR="$pkgdir" install
# FS#23283: install missing headers for OpenCascade
install -m644 src/FT{Face,Library,Size}.h "$pkgdir/usr/include/FTGL/"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
