blob: a6ff99a15ec9926dc15bb2ea731195fb1627d713 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 204775 2014-01-27 06:51:27Z jgc $
# Maintainer: Daniel Isenmann <daniel [at] archlinux.org>
# Contributor: dorphell <dorphell@gmx.net>
pkgname=gc
pkgver=7.4.0
pkgrel=1
pkgdesc="A garbage collector for C and C++"
arch=('i686' 'x86_64')
url="http://www.hpl.hp.com/personal/Hans_Boehm/gc/"
license=('GPL')
source=("http://www.hpl.hp.com/personal/Hans_Boehm/gc/gc_source/${pkgname}-${pkgver}.tar.gz")
depends=('gcc-libs' 'libatomic_ops')
md5sums=('f40d9a47c90d60791eeecb484f8df5ee')
prepare() {
cd ${pkgname}-${pkgver}
sed -i 's#pkgdata#doc#' doc/doc.am
}
build() {
cd ${pkgname}-${pkgver}
autoreconf -fi
./configure --prefix=/usr --enable-cplusplus --disable-static
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
sed -i -e 's/GC_MALLOC 1L/gc 3/' doc/gc.man
install -m755 -d "${pkgdir}/usr/share/man/man3"
install -m644 doc/gc.man "${pkgdir}/usr/share/man/man3/gc.3"
}
|
