blob: d92ecb7464fae591cd8f552f9a6657772792cc3d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 151260 2012-02-25 10:17:00Z allan $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Baptiste Daroussin <baptiste.daroussin@gmail.com>
# Contributor: Grigorios Bouzakis <grbzks[at]gmail[dot]com>
# Contributor: mightyjaym <jm.ambrosino@free.fr>
pkgname=giflib
pkgver=4.1.6
pkgrel=5
pkgdesc="A library for reading and writing gif images"
url="http://sourceforge.net/projects/giflib/"
arch=('i686' 'x86_64')
license=('MIT')
depends=('libx11')
provides=("libungif=${pkgver}")
conflicts=('libungif')
replaces=('libungif')
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/giflib/${pkgname}-${pkgver}.tar.bz2)
md5sums=('7125644155ae6ad33dbc9fc15a14735f')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i '/AC_PATH_XTRA/d' configure.ac
libtoolize -f
autoreconf
./configure --prefix=/usr --disable-static
make
# libungif compatibility - instructions taken from Redhat specfile
MAJOR=`echo ${pkgver} | sed 's/\([0-9]\+\)\..*/\1/'`
gcc -shared -Wl,-soname,libungif.so.${MAJOR} -Llib/.libs -lgif -o libungif.so.${pkgver}
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -m755 libungif.so.${pkgver} "${pkgdir}/usr/lib/"
ln -sf libungif.so.${pkgver} "${pkgdir}/usr/lib/libungif.so.4"
ln -sf libungif.so.4 "${pkgdir}/usr/lib/libungif.so"
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|
