blob: 91ee40019521b4f819adf25e97bcf719c2b6070a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 159779 2012-05-26 19:57:17Z daniel $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
pkgname=gimp
pkgver=2.8.0
pkgrel=2
pkgdesc="GNU Image Manipulation Program"
arch=('i686' 'x86_64')
url="http://www.gimp.org/"
license=('GPL' 'LGPL')
depends=('pygtk' 'lcms' 'libxpm' 'libwmf' 'libxmu' 'librsvg' 'libmng' 'dbus-glib' \
'libexif' 'gegl' 'jasper' 'desktop-file-utils' 'hicolor-icon-theme' 'babl')
makedepends=('intltool' 'libwebkit' 'poppler-glib' 'alsa-lib' 'iso-codes' 'curl')
optdepends=('gutenprint: for sophisticated printing only as gimp has built-in cups print support'
'libwebkit: for the help browser'
'poppler-glib: for pdf support'
'alsa-lib: for MIDI event controller module'
'curl: for URI support')
options=('!libtool' '!makeflags')
conflicts=('gimp-devel')
install=gimp.install
source=(ftp://ftp.gimp.org/pub/gimp/v${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2 linux.gpl
uri-backend-libcurl.patch)
md5sums=('28997d14055f15db063eb92e1c8a7ebb'
'bb27bc214261d36484093e857f015f38'
'e894f4b2ffa92c71448fdd350e9b78c6')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
#patch -p1 < ../uri-backend-libcurl.patch
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
--enable-mp --enable-gimp-console --enable-gimp-remote \
--enable-python --with-gif-compression=lzw --with-libcurl \
--without-aa --without-hal --without-gvfs --without-gnomevfs
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' "${pkgdir}"/usr/lib/gimp/2.0/plug-ins/*.py
install -D -m644 "${srcdir}/linux.gpl" "${pkgdir}/usr/share/gimp/2.0/palettes/Linux.gpl"
rm "${pkgdir}/usr/share/man/man1/gimp-console.1"
ln -s gimp-console-${pkgver%.*}.1.gz "${pkgdir}/usr/share/man/man1/gimp-console.1.gz"
ln -s gimptool-2.0 "${pkgdir}/usr/bin/gimptool"
ln -sf gimptool-2.0.1.gz "${pkgdir}/usr/share/man/man1/gimptool.1.gz"
}
|
