blob: 489b1729ce41ff548e644e75d4b88083f0e7f69e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 165330 2012-08-15 21:16:25Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-applets
pkgver=3.4.1
pkgrel=2
pkgdesc="GNOME Applets"
arch=(i686 x86_64)
license=('GPL')
depends=('gnome-panel' 'libgtop' 'gucharmap' 'libnotify')
makedepends=('gnome-doc-utils' 'intltool' 'gnome-settings-daemon' 'networkmanager')
options=(!emptydirs)
url="http://www.gnome.org"
install=gnome-applets.install
source=(http://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('ec5487eb81fb29851b6336de94a329f5623e73830d61022e0e20fe3d038a415e')
build() {
cd "$pkgname-$pkgver"
PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
--sysconfdir=/etc --libexecdir=/usr/lib/gnome-applets \
--localstatedir=/var --disable-static \
--disable-scrollkeeper --disable-schemas-install \
--without-hal
make
}
package() {
cd "$pkgname-$pkgver"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install
install -m755 -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" --domain gnome-applets-3.0 "$pkgdir"/etc/gconf/schemas/*.schemas
rm -f "$pkgdir"/etc/gconf/schemas/*.schemas
}
|
