blob: 158fde19f1cec73d711556fede2509431bd56548 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 198000 2013-10-30 12:11:19Z allan $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
pkgname=gnome-bluetooth
pkgver=3.10.0
pkgrel=1
pkgdesc="The GNOME Bluetooth Subsystem"
arch=('i686' 'x86_64' 'mips64el')
url="http://live.gnome.org/GnomeBluetooth"
license=(GPL LGPL)
depends=(gtk3 hicolor-icon-theme libnotify bluez)
makedepends=(intltool gobject-introspection itstool docbook-xsl)
options=(!emptydirs)
install=gnome-bluetooth.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
61-gnome-bluetooth-rfkill.rules)
sha256sums=('7ee4ad464abfed59f04d1a471eb25cfb95fc34eeefbe4c47580dbb50df2ab712'
'8dd2d3637f380a89e72f65e6c8021e994ccbdc645f1a1b1dbffe74ac9f061f53')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--disable-desktop-update \
--disable-icon-update \
--disable-schemas-compile
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
install -m644 -D ../61-gnome-bluetooth-rfkill.rules \
"$pkgdir/usr/lib/udev/rules.d//61-gnome-bluetooth-rfkill.rules"
}
|
