blob: 1266a9f5cbb9cac991b2f41e72c63aff7ef835f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# $Id: PKGBUILD 192485 2013-08-12 21:17:35Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-control-center
pkgver=3.8.4.1
pkgrel=2
pkgdesc="The Control Center for GNOME"
license=(GPL)
arch=(i686 x86_64)
depends=(accountsservice cups-pk-helper gnome-bluetooth gnome-desktop gnome-menus
gnome-online-accounts gnome-settings-daemon gsettings-desktop-schemas gtk3
libgtop network-manager-applet sound-theme-freedesktop upower libpwquality
gnome-color-manager smbclient modemmanager)
makedepends=(gnome-doc-utils intltool docbook-xsl)
optdepends=('system-config-printer: Printer settings'
'gnome-user-share: Bluetooth and WebDAV file sharing'
'rygel: media sharing'
'vino: screen sharing'
'openssh: remote login')
groups=(gnome)
url="http://www.gnome.org"
install=gnome-control-center.install
options=('!libtool' '!emptydirs')
source=(http://download.gnome.org/sources/$pkgname/${pkgver::3}/$pkgname-$pkgver.tar.xz
no-deprecated-upower.diff)
sha256sums=('3cfc5b93ca12f498c075f5b5356e0af4a0aaee003c0a90a4309bc12876f40c55'
'4182fa082b071c840bc0a6e981dad3c070602cae473229227e81bdaa2b5f8c23')
prepare() {
cd $pkgname-$pkgver
patch -Np1 -i ../no-deprecated-upower.diff
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$pkgname --disable-static
#https://bugzilla.gnome.org/show_bug.cgi?id=656229
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# Fix a warning
chown 102:0 "$pkgdir/usr/share/polkit-1/rules.d"
chmod 700 "$pkgdir/usr/share/polkit-1/rules.d"
}
|
