blob: 9c5db6383608030fbda1b9e99d456a0ae3bd6b08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 142419 2011-11-09 07:46:48Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-control-center
pkgver=3.2.2
pkgrel=1
pkgdesc="The Control Center for GNOME"
arch=('i686' 'x86_64' 'mips64el')
depends=('gtk3' 'gsettings-desktop-schemas' 'gnome-menus' 'gnome-desktop' 'gnome-settings-daemon' 'upower' 'libgtop' 'cups-pk-helper' 'accountsservice' 'sound-theme-freedesktop' 'gnome-online-accounts' 'network-manager-applet')
optdepends=('mesa-demos-libre: provides glxinfo for graphics information'
'apg: adds password generation for user accounts'
'gnome-color-manager: for color management tasks')
makedepends=('gnome-doc-utils' 'intltool')
url="http://www.gnome.org"
groups=('gnome')
install=gnome-control-center.install
license=('GPL')
options=('!libtool' '!emptydirs')
source=(http://download.gnome.org/sources/${pkgname}/3.2/${pkgname}-${pkgver}.tar.xz)
sha256sums=('e675f8cfde06775919eb0c9fa4ee8c61310702989eecac6083098beb5afd9369')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--disable-scrollkeeper --disable-update-mimedb
#https://bugzilla.gnome.org/show_bug.cgi?id=656229
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
