blob: 17918d2fe25362bc04a9f4fc99949bf2d1cdae9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 203381 2014-01-09 06:32:24Z fyan $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=gnome-settings-daemon
pkgver=3.10.2
pkgrel=3
pkgdesc="The GNOME Settings daemon"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
depends=('dconf' 'gnome-desktop' 'gsettings-desktop-schemas' 'hicolor-icon-theme' 'libcanberra-pulse' 'libnotify'
'libsystemd' 'libwacom' 'pulseaudio' 'pulseaudio-alsa' 'upower' 'libibus' 'librsvg' 'libgweather' 'geocode-glib' 'geoclue2'
'nss')
makedepends=('intltool' 'xf86-input-wacom' 'libxslt' 'docbook-xsl')
options=('!emptydirs')
install=gnome-settings-daemon.install
url="http://www.gnome.org"
groups=('gnome')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
0001-power-use-gnome_rr_output_get_min_backlight_step.patch)
sha256sums=('808899c6e434ecb71f42d3ac022dc51f5963bdf2478f4634078483f9e8a78264'
'e83d2d496506c3964236e376d0ec8f844e5b6850f5e2d2fea9208bd008c19f54')
prepare() {
cd $pkgname-$pkgver
# FS#37224
patch -Np1 -i ../0001-power-use-gnome_rr_output_get_min_backlight_step.patch
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$pkgname --disable-static
#https://bugzilla.gnome.org/show_bug.cgi?id=656231
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
