blob: 37e19bfb2a621176785ccf55c9c2ae5111874ed3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 141031 2011-10-22 05:09:05Z eric $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: Mark Schneider <queueRAM@gmail.com>
pkgname=gnucash
pkgver=2.4.8
pkgrel=1
pkgdesc="A personal and small-business financial-accounting application"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnucash.org"
license=("GPL")
depends=('gtkhtml' 'slib' 'goffice' 'libgnomeui' 'libdbi-drivers' 'aqbanking' 'desktop-file-utils')
makedepends=('intltool')
optdepends=('evince: for print preview'
'perl-finance-quote: for stock information lookups'
'perl-date-manip: for stock information lookups')
options=('!libtool' '!makeflags')
install=gnucash.install
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
sha1sums=('cdd8793bc8e8cbb433a0237007023f4973a51781')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --mandir=/usr/share/man \
--sysconfdir=/etc --libexecdir=/usr/lib --enable-ofx --enable-aqbanking
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
install -dm755 "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain gnucash "${pkgdir}"/etc/gconf/schemas/*.schemas
rm -f "${pkgdir}"/etc/gconf/schemas/*.schemas
}
|
