blob: 0986173ff2e71d263e80722e84c371cc5ae3e365 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 125165 2011-05-25 19:05:49Z foutrelis $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Kritoke <typeolinux@yahoo.com>
pkgname=gnumeric
pkgver=1.10.15
pkgrel=2
pkgdesc="A GNOME Spreadsheet Program"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnome.org/projects/gnumeric/"
license=('GPL')
depends=('goffice' 'gconf' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('intltool' 'python2' 'gnome-doc-utils' 'pygobject' 'psiconv')
optdepends=('pygobject: for python plugin support'
'psiconv: for Psion 5 file support'
'yelp: for viewing the help manual')
install=gnumeric.install
options=('libtool')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('4343a8e72bd19380d83ab5d4937388b2327e0dbb6187296e66dc7ca2d2b9025a')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-schemas-install --enable-ssindex
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain gnumeric "${pkgdir}"/etc/gconf/schemas/*.schemas
rm -rf "${pkgdir}/etc/gconf"
}
|
