blob: f4568beb9687b9d3ab7ee13741333a0bf8c4372a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 198041 2013-10-30 12:26:38Z allan $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Kritoke <typeolinux@yahoo.com>
pkgname=gnumeric
pkgver=1.12.8
pkgrel=1
pkgdesc="A GNOME Spreadsheet Program"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnome.org/projects/gnumeric/"
license=('GPL')
depends=('goffice' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('intltool' 'psiconv' 'pygobject-devel' 'gnome-doc-utils'
'gobject-introspection')
optdepends=('python2-gobject: for python plugin support'
'perl: for perl plugin support'
'psiconv: for Psion 5 file support'
'yelp: for viewing the help manual')
install=gnumeric.install
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz
revert-warnings.patch)
sha256sums=('02688fb6c32c28db2eb4e9a8e012cf1386f4f3a18b4c94f5ecdd13342521ec76'
'bcafca016b809000c2a5bf911e2e3dfa4de28f9e541d9964574cac5c7ce09e53')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np0 -i ../revert-warnings.patch
# Remove invalid mime type. (FS#26338)
sed -i -e 's/zz-application\/zz-winassoc-xls;//' gnumeric.desktop.in
autoreconf -fi
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-schemas-compile --enable-introspection
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
