blob: bcf58826274c2e049e643d67f10da3e6496f7129 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 160479 2012-06-02 10:26:10Z bluewind $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Kritoke <typeolinux@yahoo.com>
pkgname=gnumeric
pkgver=1.10.17
pkgrel=2
pkgdesc="A GNOME Spreadsheet Program"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnome.org/projects/gnumeric/"
license=('GPL')
depends=('goffice' 'gconf' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('intltool' 'python2' 'gnome-doc-utils' 'pygobject' 'psiconv')
optdepends=('pygobject: for python plugin support'
'psiconv: for Psion 5 file support'
'yelp: for viewing the help manual')
install=gnumeric.install
options=('libtool')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz)
sha256sums=('8f105a10dc0dd47e14df2879591d2f28482fd03809fa95977dd4d1470a02f963')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Remove invalid mime type. (FS#26338)
sed -i -e 's/zz-application\/zz-winassoc-xls;//' gnumeric.desktop.in
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-schemas-install --enable-ssindex
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain gnumeric "${pkgdir}"/etc/gconf/schemas/*.schemas
rm -rf "${pkgdir}/etc/gconf"
}
|
