blob: c9aebc69878aa6b917598a9f9d59d4dae20f789e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 147145 2012-01-23 07:56:33Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Hokum <hokum_at_mail_dot_ru>
pkgname=gptfdisk
pkgver=0.8.2
pkgrel=1
pkgdesc="A text-mode partitioning tool that works on Globally Unique Identifier (GUID) Partition Table (GPT) disks"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.rodsbooks.com/gdisk/"
license=('GPL2')
depends=('gcc-libs' 'util-linux' 'popt' 'icu')
provides=("gdisk=$pkgver")
conflicts=('gdisk')
replaces=('gdisk')
source=(http://downloads.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
sha256sums=('b1159027ca459661f04bc3bac8e79381895933ee214c4d6dba49b7d27204e5d3')
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package () {
cd "$srcdir/$pkgname-$pkgver"
install -d "$pkgdir"/{sbin,usr/share/{doc/gdisk,man/man8}}
install -t "$pkgdir/sbin" {,c,s}gdisk fixparts
install -m644 -t "$pkgdir/usr/share/man/man8" {{,c,s}gdisk,fixparts}.8
install -m644 -t "$pkgdir/usr/share/doc/gdisk" README NEWS
}
# vim:set ts=2 sw=2 et:
|
